PROGRAM GRATICULE
C   CREATES A SIMPLE GRID OF LATITUDE AND LONGITUDE LINES,
C   SUITABLE FOR PROJECTION BY -LL2XY- TO FORM A .DIG FILE
C   FOR USE AS A BACKGROUND IN PLOTS, OR IN FINITE-ELEMENT
C   GRID EDITING WITH -DRAWGRID-.
C
C   BY PETER BIRD, SEPTEMBER 1992
C
       REAL LATMAX,LATMIN,LONMAX,LONMIN
       CHARACTER*40 FILNAM
C
C   FOLLOWING STATEMENTS SET LINE SPACING, IN DEGREES:
       WRITE (*,1)
    1  FORMAT (/' THIS PROGRAM CREATES A LATITUDE/LONGITUDE GRID'/
     +          ' (A GRATICULE) IN .DIG FORMAT, WHICH CAN THEN'/
     +          ' BE PROCESSED BY -LL2XY- INTO A PARTICULAR MAP',
     +          ' PROJECTION'/
     +          ' FOR USE WITH -DRAWGRID- OR GRAPHICS PROGRAMS.'/ /
     +          ' ENTER THE GRID SPACING, IN DEGREES: '\)
      READ (*,*) DELTA
C
C   FOLLOWING LINES SET LIMITS ON LATITUDE (N = +) AND LONGITUDE (E = +).
C     (NOTE THAT LONGITUDE IS NOT LIMITED TO +-180.)
       WRITE (*,2)
    2  FORMAT (/' ENTER THE MOST NORTHERN LATITUDE (N = +, S = -): '\)
       READ (*,*) LATMAX
       WRITE (*,3)
    3  FORMAT (/' ENTER THE SOUTHERN LIMIT OF LATITUDE: '\)
       READ (*,*) LATMIN
       WRITE (*,4)
    4  FORMAT (/' ENTER THE WESTERNMOST LONGITUDE (E = +, W = -): '\)
       READ (*,*) LONMIN
       WRITE (*,5)
    5  FORMAT (/' ENTER THE EASTERNMOST LONGITUDE: '\)
       READ (*,*) LONMAX
       WRITE (*,6)
    6  FORMAT (/' ENTER NAME FOR OUTPUT FILE (INCLUDE .DIG?): '\)
       READ (*,7) FILNAM
    7  FORMAT (A)
       OPEN (UNIT=1,FILE=FILNAM)
C
       NROW=1+(LATMAX-LATMIN)/DELTA
       NCOL=1+(LONMAX-LONMIN)/DELTA
C
       DO 100 IROW=1,NROW
            THELAT=LATMAX-(IROW-1)*DELTA
            WRITE (1,10) THELAT
   10       FORMAT ('LATITUDE ',F7.2,' DEGREES NORTH')
            WRITE (*,11) THELAT
   11       FORMAT (' LATITUDE ',F7.2,' DEGREES NORTH')
            DO 90 ICOL=1,NCOL
                 THELON=LONMIN+(ICOL-1)*DELTA
                 WRITE (1,20) THELON,THELAT
   20            FORMAT (' ',SP,1P,E12.5,',',E12.5)
   90       CONTINUE
            WRITE (1,99)
   99       FORMAT ('*** end of line segment ***')
  100  CONTINUE      
C
       DO 200 ICOL=1,NCOL
            THELON=LONMIN+(ICOL-1)*DELTA
            WRITE (1,110) THELON
  110       FORMAT ('LONGITUDE ',F7.2,' DEGREES EAST')
            WRITE (*,111) THELON
  111       FORMAT (' LONGITUDE ',F7.2,' DEGREES EAST')
            DO 190 IROW=1,NROW
                 THELAT=LATMAX-(IROW-1)*DELTA
                 WRITE (1,20) THELON,THELAT
  190       CONTINUE
            WRITE (1,99)
  200  CONTINUE      
       STOP
       END